#!/usr/local/bin/perl -w
# class-struct.pl -- C-Strukturen als Klassen mit Class::Struct

use Class::Struct;                         # Standardmodul

# Wir deklarieren erst einige Klassen
# mit Hilfe der struct()-Funktion:

struct Address => {                        # Address-Klasse
          street  => '$',            # Ein skalarer Wert
          house   => '$',            # Noch ein skalares Attribut
          zipcode => '$' };          # Und wieder so eines.

struct Person  => {                        # Person-Klasse
          name     => '$',           # Skalarer Name
          phone    => '$',           # Skalare Telefonnummer
          location => 'Address' };   # Benutzerdefinertes Attribut

struct Class   => {                        # Class-Klasse
          instructor => 'Person',    # Benutzerdefiniertes Attribut
          students   => '@',         # Referenz auf Array
          location   => 'Address' }; # Benutzerdefiniertes Attribut

# Die drei Klassen haben schon Konstruktoren new()
# und Akzessormethoden mit denselben Namen wie die Attribute.

my $profaddr = Address->new();
$profaddr->street("pine road");
$profaddr->house("42bis");
$profaddr->zipcode("90210");

my $prof = Person->new();
$prof->name("perl d. interpreter");
$prof->phone("555-5555");
$prof->location($profaddr);

my $class = Class->new();
$class->instructor($prof);
$class->location($profaddr);
$class->students([]);           # Noch keine Studenten

# Zeigen wir einmal unsere Klasse $class an:
use Data::Dumper;
print Dumper($class);