#!/usr/local/bin/perl -w
# ioresvar.pl -- Reservierte Variablen der Ein-/Ausgabe:

@mylist = 'a' .. 'e';                  # Irgendeine Beispielliste

# Der Output-Field-Separator als Trenner zwischen einzelnen Feldern.
{
    print @mylist, "\n";                   # abcde, da $, = '' ($OFS)
    local $, = ':';                        # neuer Feldtrenner
    print @mylist, "\n";                   # a:b:c:d:e:, da $, = ':'
}

# Der Output-Record-Separator trennt die Ausgabe einelner
# print()-Statements voneinander
{
    foreach $elem (@mylist) { print $elem; }  # abcde
    local $\ = "\n";                          # neuer Satztrenner
    foreach $elem (@mylist) { print $elem; }  # ein Element pro Zeile
}

# Die Nummer der aktuell eingelesenen Zeile in $.
# Der Name der gerade eingelesenen Datei in $ARGV
# ACHTUNG! $. wird bei einem Dateiwechsel nicht zurueckgesetzt
while (<>) { print "$ARGV($.): $_"; }

# Der Input Record Separator, der ja normalerweise \n ist,
# kann auch veraendert werden, so dass damit ganze
# Absaetze eingelesen werden koennen:
{
    local $/ = '';                       # Absatz-Modus
    while (<DATA>) { chomp;
                     print "\n", "-"x10, "\n",
                     "Paragraph:\n", $_; }
}

__DATA__
From: "James T. Kirk" <jtkirk@ncc1701.federation.earth>
To: "Jean-Luc Picard" <jlpicard@ncc1701d.federation.earth>
Cc: "Q" <q@the-continuum>
Date: 32341.11 (Stardate)
Subject: Prime Directive sucks

Hi Jean-Luc!

That Prime Directive shouldn't stop you from drinking beer
with earthlings of the 21st century.
As long as you don't tell'em how to brew arcturian ale,
this won't interfere with their civilization :-)

cu, -K.