#!/usr/local/bin/perl -w
# pop3.pl -- Hole E-Mails mit dem POP3-Protokoll und Net::POP3

use Net::POP3;           # Aus der libnet-CPAN-Library

# ----- CONFIG BEGIN ------------------------------------------
use constant MAILHOST => "mail.kamp.net"; # Der POP3-Server
use constant MAILUSER => $ENV{'USER'};    # POP3-Account
use constant MAILPASS => "pass_xyzzy";    # oder User fragen...
use constant TIMEOUT  => 60;              # in Sekunden
# ----- CONFIG END --------------------------------------------

# Erzeuge ein POP3-Objekt
$pop3 = Net::POP3->new(MAILHOST,
                       'Timeout' => TIMEOUT)
    or die "can't create a new pop3 object: $!\n";

# Beim POP3-Server einloggen
$pop3->login(MAILUSER, MAILPASS)
    or die "can't login to the pop3 server: $!\n";

# Hole Liste aller noch nicht geloeschter Mails.
# Schluessel: Nummer der nicht geloeschten Nachrichten,
# Werte: Laenge der Nachricht in Bytes.
$phash = $pop3->list();

# Lies alle nicht geloeschten Mails
foreach my $elem (sort keys %{ $phash }) {
    # Hole die $elem-nte Mail
    my $ptext = $pop3->get($elem);

    # Nachricht ausgeben
    foreach my $line (@{ $ptext }) { print $line; }

    # OPTIONAL: Mail beim POP3-Server als geloescht markieren
    $pop3->delete($elem);
}

# Explizit Verbindung mit quit() beenden,
# damit der POP3-Server die zum Loeschen markierten Mails
# auch wirklich loescht.
$pop3->quit();