#!/usr/local/bin/perl -w
# symrefs-example.pl -- Beispiele symbolischer Referenzen

no  strict 'refs';            # Lasse symbolische Referenzen zu
use vars qw($var @ary %hash); # -w-Flag befriedigen

# Erst einige Variablen
$var  = 4711;
@ary  = ( 'a', 9, 'p', ' ', 'h', ' ' );
%hash = ( Wall => 'Larry', Kirk => 'Jim', Spock => 'Mr.' );
sub f1  { return "Blah"; }

# Und jetzt die symbolischen Referenzen
$pvar  = 'var';          # Name einer skalaren Variablen
$par   = 'ary';          # Name eines Arrays
$phash = 'hash';         # Name eines Hashs
$psub  = 'f1';           # Name einer Subroutine

# Dereferenzierung von symbolischen Referenzen:
print 'Contents $var : ', ${$pvar}, "\n";
print 'Contents @ary : ', "(", join(',',  @{$par}), ")\n";
print 'Contents %hash: ', "(", join(', ', map { "$_ => ${$phash}{$_}" }
                                          sort keys %{$phash}), ")\n";
print 'Calling f1    : ', &{$psub}(), "\n";

# Aenderung von Werten ueber symbolische Referenzen:
$par->[0] = 'new value';
$phash->{'Kirk'} = 'Jim Tiberius';
delete $phash->{'Spock'};

print 'New Array: ', "(", join(',',  @ary), ")\n";
print 'New Hash : ', "(", join(', ', map { "$_ => $hash{$_}" }
                                     sort keys %hash), ")\n";